Example code is for an older version of Toolkit, newer code is available.
' Copyright (c) 2020 ActivePDF, Inc.
' ActivePDF Toolkit 2017
' Example generated 10/01/20
Dim FSO, strPath, intOpenOutputFile, intOpenInputFile, _
strText, textWidth, textHeight, intCopyForm
' Get current path
Set FSO = CreateObject("Scripting.FileSystemObject")
strPath = FSO.GetFile(Wscript.ScriptFullName).ParentFolder & "\"
Set FSO = Nothing
' Instantiate Object
Set oTK = CreateObject("APToolkit.Object")
' Create the new PDF file
intOpenOutputFile = oTK.OpenOutputFile(strPath & "new.pdf")
If intOpenOutputFile <> 0 Then
ErrorHandler "OpenOutputFile", intOpenOutputFile
End If
' Open the template PDF
intOpenInputFile = oTK.OpenInputFile(strPath & "PDF.pdf")
If intOpenInputFile <> 0 Then
ErrorHandler "OpenInputFile", intOpenInputFile
End If
' Add a 'confidential' watermark
strText = "Confidential"
oTK.SetFont "Helvetica", 72, -1
textWidth = oTK.GetTextWidth(strText)
textHeight = oTK.GetTextHeight(strText)
oTK.SetTextColor 200, 200, 200, 0, -1
oTK.PrintText (612 - textWidth) / 2, (792 - textHeight) / 2, strText, -1
oTK.ResetTextColor -1
' Copy the template (with the stamping changes) to the new file
' Start page and end page, 0 = all pages
intCopyForm = oTK.CopyForm(0, 0)
If intCopyForm <> 1 Then
ErrorHandler "CopyForm", intCopyForm
End If
' Close the new file to complete PDF creation
oTK.CloseOutputFile
' Release Object
Set oTK = Nothing
' Process Complete
Wscript.Echo("Done!")
' Error Handling
Sub ErrorHandler(method, outputCode)
Wscript.Echo("Error in " & method & ": " & outputCode)
End Sub
